The Russian Electronic Developer Magazine
	Русский электронный журнал разработчика

Похвальное слово EPM

О, сколько нам открытий чудных
Готовит просвещенья дух...
А.С.Пушкин

Замечание.

В статье рассматривается вопрос построения комфортной среды разработки программ. Все нижеизложенные рекомендации основаны на личных предпочтениях автора и не обязательны для применения.

Содержание

• Введение
• Система помощи
• Подсветка ключевых слов
• Макросы REXX для работы в кольце
• Документирование исходных текстов
• Полоса инструментов
• Настройка при запуске
• Заключение

Введение

>>> Назад к оглавлению.

Система помощи

• пользователь должен установить курсор на выбранную лексему (например, имя функции) и нажать комбинацию клавиш Ctrl-H, либо, нажав кнопку Ctrl, дважды щелкнуть кнопкой 1 мыши;
• EPM ищет индексный файл - сначала в текущем каталоге, потом в каталогах, указанных в переменных среды EPMPATH и DPATH, затем в каталоге, из которого загружен EPM, и, наконец, в каталогах, указанных в переменной среды PATH;
• затем EPM отыскивает в индексном файле ссылку на выбранную лексему и запускает программу просмотра помощи.

   SET HELPNDX=DDE4.NDX+EPMKWHLP.NDX

Замечание.

Автор не располагает документацией с описанием структуры индексных файлов. Поэтому все предположения относительно этой структуры основаны на догадках (впрочем, весьма прозрачных), сделаных на основе анализа доступных индексных файлов.

Индексный файл - это простой текстовый файл, состоящий из набора управляющих и индексных строк. Управляющие строки располагаются в начале файла и имеют следующий формат:

   ОПЕРАТОР: параметры

• EXTENSIONS: символ
  Задает символ-заменитель для шаблона поиска в индексных строках, обычно (*).
  
  
• DESCRIPTION: строка
  Строка-комментарий, содержащая описание индексного файла.

   (шаблон поиска, шаблон командной строки)

   EXTENSIONS: *
   DESCRIPTION: Custom Index for Toolkit
   (fopen, view clr ~)
   (Win*, view pmref ~)
   ...

   view pmref WinCreateWindow

   (NW*, cmd.exe /c start /c /f /win winhelp.exe c:\nwsdk\winhelp\c_apiref.hlp)

   (MENUITEM, cmd.exe /c start /c /f /win links.exe -no-connect file://C:/HTML/rc.html#~)

   /* Get help                       */
   /* Copyleft VicTor Smirnoff, 2001 */

   'extract /filename'
   fname = filespec( "name", filename.1 )
   d = lastpos( '.', fname )

   if d > 0 then
   do
      fext = translate( substr( fname, d+1 ) )

      select
      when wordpos( fext, "RC DLG" ) > 0  then
         xHelp = 'EPMKWRC.NDX'
      when wordpos( fext, "CMD ERX" ) > 0  then
         xHelp = 'EPMKWRX.NDX'
      otherwise
         xHelp = ''
      end

      rc = setlocal()
      xOld = Value( 'HELPNDX', , 'OS2ENVIRONMENT' )
      if xHelp \= '' then
      do
         xNew = xHelp||'+EPMKWHLP.NDX'
         if xOld \= '' then xNew = xHelp||'+'||xOld
         rc = Value( 'HELPNDX', xNew, 'OS2ENVIRONMENT' )
      end
      'dokey c+H'
      rc = endlocal()

   end

>>> Назад к оглавлению.

Подсветка ключевых слов

   /* Hilite keywords                */
   /* Copyleft VicTor Smirnoff, 2001 */

   'extract /filename'
   fname = filespec( "name", filename.1 )
   d = lastpos( '.', fname )

   if d > 0 then
   do
      fext = translate( substr( fname, d+1 ) )

      select
      when wordpos( fext, "C H CPP HPP" ) > 0 then
         fext = 'C'
      when wordpos( fext, "RC DLG" ) > 0  then
         fext = 'RC'
      when wordpos( fext, "BAT CMD ERX VRX" ) > 0  then
         fext = 'CMD'
      when wordpos( fext, "HTM HTML" ) > 0  then
         fext = 'HTM'
      otherwise
         nop
      end

      'extract /userstring'
      parse upper var userstring.1 xA'HILITE='xHi';'xB

      yHi = 1
      if xHi = 1 then yHi = 0

      call etksetfilefield 'userstring', xA||'HILITE='||yHi||';'||xB

      'toggle_parse '||yHi||' epmkwds.'||fext
   end

>>> Назад к оглавлению.

Макросы REXX для работы в кольце

   /* Add all source files           */
   /* Copyleft VicTor Smirnoff, 2001 */

   currentID = rxGetFileId()
   'edit *.c,*.cpp,*.h,*.hpp,*.rc,*.dlg'

   newID = rxGetFileId()
   xID = 0
   do while xID \= newID
      call hilite.erx
      call etkprocesseditkey "NEXT_FILE"    /* dokey F12 */
      xID = rxGetFileId()
   end

   xID = rxGetFileId()
   do while xID \= currentID
      call etkprocesseditkey "NEXT_FILE"    /* dokey F12 */
      xID = rxGetFileId()
   end
   exit

   rxGetFileId: procedure
      call etkprocesseditkey "UNMARK"
      call etkprocesseditkey "MARK_LINE"
      'extract /getmark'
      call etkprocesseditkey "UNMARK"
      return getmark.5

   /* Save all modified files        */
   /* Copyleft VicTor Smirnoff, 2001 */

   currentID = rxGetFileId()
   xID = 0
   do while xID \= currentID
      'extract /modify'
      if modify.1 \= 0 then 'save'
      call etkprocesseditkey "NEXT_FILE"    /* dokey F12 */
      xID = rxGetFileId()
   end
   exit

   rxGetFileId: procedure
      call etkprocesseditkey "UNMARK"
      call etkprocesseditkey "MARK_LINE"
      'extract /getmark'
      call etkprocesseditkey "UNMARK"
      return getmark.5

/* Toggle mono/proportional fonts */
/* Copyleft VicTor Smirnoff, 2001 */

   'extract /font'
   if font.1 = 1 then
      call etksetfilefield 'font', 2
   else
      call etksetfilefield 'font', 1

>>> Назад к оглавлению.

Документирование исходных текстов

   /* Insert comment                 */
   /* Copyleft VicTor Smirnoff, 2001 */

   'extract /filename/last'
   fname = filespec( "name", filename.1 )
   d = lastpos( '.', fname )

   if d > 0 then
   do
      fext = translate( substr( fname, d+1 ) )

      select
      when wordpos( fext, "C H CPP HPP RC DLG CMD ERX VRX" ) > 0 then
      do
         call etksetfilefield 'col', 1
         call etkinserttext substr('/',1,75,'*')||'/'
         call etkinserttext substr('/*',1,74,' ')||'*/'
         call etkinserttext substr('/',1,75,'*')||'/'
      end
      otherwise
         nop
      end

   end

   /**************************************************************************/
   /* MyCoolFunction()                                                       */
   /*========================================================================*/
   /* Описание:                                                              */
   /*                                                                        */
   /* Синтаксис:                                                             */
   /*    rc = MyCoolFunction(idWho,cName,idWhere,cStreet);                   */
   /*                                                                        */
   /* Параметры:                                                             */
   /*    idWho                                                               */
   /*    cName                                                               */
   /*    idWhere                                                             */
   /*    cStreet                                                             */
   /*                                                                        */
   /* Возврат:                                                               */
   /*    rc                                                                  */
   /*                                                                        */
   /*------------------------------------------------------------------------*/
   INT MyCoolFunction( INT idWho, CHAR *cName, INT idWhere, CHAR *cStreet )
   {
      . . .
   }
   /*------------------------------------------------------------------------*/
   /* Конец функции MyCoolFunction()                                         */
   /**************************************************************************/

   /**************************************************************************/
   /* MyCoolRoutine.c - исходные тексты программы                            */
   /*                                                                        */
   /*========================================================================*/
   /* (c) VicTor Smirnoff, 2001                         sva@water.karelia.ru */
   /*------------------------------------------------------------------------*/
   #define INCL_PM
   #include <os2.h>

      . . .


   /*------------------------------------------------------------------------*/
   /* Конец файла MyCoolRoutine.c                                            */
   /**************************************************************************/

>>> Назад к оглавлению.

Полоса инструментов

>>> Назад к оглавлению.

Настройка при запуске

   /* Profile REXX                   */
   /* Copyleft VicTor Smirnoff, 2001 */

   AF_CHAR        =   1   /* константы стиля клавиш */
   AF_VIRTUALKEY  =   2
   AF_SCANCODE    =   4
   AF_SHIFT       =   8
   AF_CONTROL     =  16
   AF_ALT         =  32
   AF_LONEKEY     =  64

   VK_F1        = 32
   VK_ALT       = 11

   MIS_SEPARATOR = 4

   /* Настройка опций */
   /* При поиске, по умолчанию, не учитывается регистр */
   'universal default_search_options C'
   /* При загрузке файла преобразовать табуляции в пробелы */
   'universal default_edit_options /nt'
   /* Удалить пробелы на концах строк при сохранении файла */
   'universal default_save_options /s'

   /* Настройка горячих клавиш */
   /* ASCII 104 = 'h' */
   /* ASCII 122 = 'z' */
   /* Ctrl-h получить справку */
   /* Ctrl-z заключить бокс в рамку комментариев C */
   /* Alt-z  убрать рамку вокруг бокса */
   'buildaccel *' (AF_CHAR + AF_CONTROL)  104 9302 'rx gethelp'
   'buildaccel *' (AF_CHAR + AF_CONTROL)  122 9301 'box c'
   'buildaccel *' (AF_CHAR + AF_ALT)      122 9300 'box e'
   /* Запрещает использование клавиши Alt для перехода на полосу меню.*/
   'buildaccel *' (AF_VIRTUALKEY+AF_LONEKEY) VK_ALT 9399 'sayerror F10=полоса меню'
   'activateaccel'  /* Нет аргумента => используется текущее имя таблицы. */

   /* Настройка меню */
   'buildsubmenu default 1990 Исходники 0 0'
   'buildmenuitem default 1990 1991 Подсветка 0 0 rx hilite'
   'buildmenuitem default 1990 1992 Добавить_Все 0 0 rx addall'
   'buildmenuitem default 1990 1993 x' MIS_SEPARATOR '0'
   'buildmenuitem default 1990 1994 Вставить_Заголовок_Файла 0 0 rx insertheader'
   'buildmenuitem default 1990 1995 Вставить_Заголовок_Функции 0 0 rx insertfunction'
   'buildmenuitem default 1990 1996 Вставить_Комментарий 0 0 rx insertcomment'
   'showmenu default'

>>> Назад к оглавлению.

Заключение

>>> Назад к оглавлению.

Примеры полосы инструментов, битмапы и тексты макросов REXX и находятся в архиве myepm.zip.

Успехов,

VicTor Smirnoff

Интересные ссылки:

Комментариев к странице: 0 | Добавить комментарий

Редактор: Дмитрий Бан
Оформление: Евгений Кулешов